Option Explicit

Dim numMagazzini
Dim IdMagazzino()
Dim TempiMagazzino()
Dim TestoDefault

numMagazzini=5
Redim IdMagazzino(numMagazzini)
Redim TempiMagazzino(numMagazzini)

TestoDefault="L'ordine contiene uno o piu' articoli non disponibili in nessun magazzino"

IdMagazzino(1) = 1
TempiMagazzino(1)="Consegna immediata"

IdMagazzino(2) = 2
TempiMagazzino(2)="2gg. lavorativi"

IdMagazzino(3) = 7
TempiMagazzino(3)="5gg. lavorativi"

IdMagazzino(4) = 8
TempiMagazzino(4)="10gg. lavorativi"

IdMagazzino(5)=9
TempiMagazzino(5)="20gg. lavorativi"

'======================================================================================
'======================================================================================
Dim livelloOrdine
Dim RigaDoc
Dim Articolo
Dim i
Dim livelloRiga

livelloOrdine=1
For Each RigaDoc In Doc.DocRows
    Set Articolo=RigaDoc.Product
    If Articolo.Id>0 Then
        LivelloRiga=1000
        For i=1 to numMagazzini
            If IdMagazzino(i)<=0 Then
                Rdy.ShowMessage "Errata configurazione dei codici magazzino"
            Else
                If Articolo.QtyInventory(IdMagazzino(i))>=RigaDoc.Quantity Then
                    ' Quantita' di magazzino sufficiente per coprire la riga ordine
                    LivelloRiga=i
                    Exit For 
                End If
            End If
        Next   
        If LivelloRiga=1000 Then
            ' Nessun magazzino copre la quantita' in ordine
            LivelloOrdine=1000
            Exit For
        ElseIf LivelloRiga>0 Then
            If LivelloRiga>LivelloOrdine Then
                ' Incrementa il tempo di consegna dell'ordine se la riga ha una tempo di consegna superiore dei precedenti
                LivelloOrdine=LivelloRiga
            End If
        End If
    End If
	Set Articolo=Nothing
Next

If LivelloOrdine=1000 Then
    Response.Write(TestoDefault)
Else
    If (LivelloOrdine>=1)AND(LivelloOrdine<=numMagazzini) Then
        Response.Write(TempiMagazzino(LivelloOrdine))
    End If
End If